#
# EKS Worker Nodes Resources
#  * IAM role allowing Kubernetes actions to access other AWS services
#  * EKS Node Group to launch worker nodes
#

resource "aws_iam_role" "company-node" {
  name = "${var.cluster-name}-node-iam-role"

  assume_role_policy = <<POLICY
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Effect": "Allow",
      "Principal": {
        "Service": "ec2.amazonaws.com"
      },
      "Action": "sts:AssumeRole"
    }
  ]
}
POLICY
}

resource "aws_iam_role_policy_attachment" "company-node-AmazonEKSWorkerNodePolicy" {
  policy_arn = "arn:aws:iam::aws:policy/AmazonEKSWorkerNodePolicy"
  role       = aws_iam_role.company-node.name
}

resource "aws_iam_role_policy_attachment" "company-node-AmazonEKS_CNI_Policy" {
  policy_arn = "arn:aws:iam::aws:policy/AmazonEKS_CNI_Policy"
  role       = aws_iam_role.company-node.name
}

resource "aws_iam_role_policy_attachment" "company-node-AmazonEC2ContainerRegistryReadOnly" {
  policy_arn = "arn:aws:iam::aws:policy/AmazonEC2ContainerRegistryReadOnly"
  role       = aws_iam_role.company-node.name
}

resource "aws_eks_node_group" "company" {
  cluster_name    = aws_eks_cluster.company.name
  node_group_name = "${var.cluster-name}-node-group"
  node_role_arn   = aws_iam_role.company-node.arn
  subnet_ids      = aws_subnet.company[*].id
  instance_types  = ["m5.xlarge"]
  tags = {
    Department = "Engineering"
    Contact    = "engineering@company.com"
    Project    = "EKS Terraform Matrixx"
    Name       = "EKS Terraform Matrixx Node"
  }

  scaling_config {
    desired_size = 2
    max_size     = 2
    min_size     = 2
  }

  depends_on = [
    aws_iam_role_policy_attachment.company-node-AmazonEKSWorkerNodePolicy,
    aws_iam_role_policy_attachment.company-node-AmazonEKS_CNI_Policy,
    aws_iam_role_policy_attachment.company-node-AmazonEC2ContainerRegistryReadOnly,
  ]
}