Replacing old template_file code

[mail2]

I am trying to update very old Terraform code removing the Template provider which has been deprecated.

I have completed pretty much all of the upgrade but am really struggling updating this nested template file bit of code.

data "template_file" "vpn_routes" {
   count = length(data.template_file.all_vpc_cidr_blocks.*.rendered)
  template = "${cidrhost(
    element(
      data.template_file.all_vpc_cidr_blocks.*.rendered,
      count.index,
    ),
    0,
    )} ${cidrnetmask(
    element(
      data.template_file.all_vpc_cidr_blocks.*.rendered,
      count.index,
    ),
  )}"
}

data "template_file" "all_vpc_cidr_blocks" {
  count = length(
    data.terraform_remote_state.other_vpcs.*.outputs.vpc_cidr_block,
  ) + 1
  template = element(
    concat(
      data.terraform_remote_state.other_vpcs.*.outputs.vpc_cidr_block,
     [data.terraform_remote_state.mgmt_vpc.outputs.vpc_cidr_block],
    ),
    count.index,
  )
}

This output is then posted into the userdata

  user_data = templatefile(
    "${path.module}/user-data/user-data.sh",
    {
    ...
     vpn_routes = join(
         " ",
          formatlist(
            "--vpn-route \"%s\" ",
            concat(
              data.template_file.vpn_routes.*.rendered,
              var.additional_vpn_routes,
            ),
        ),

Is there a guide anywhere, or some documentation people could suggest to help me out?

[apparentlymart]

Hi @mail2,

This example seems like a strange use of template_file because as far as I can tell all of the interpolations are being handled by Terraform Core before even asking the template provider; the template provider is then just “rendering” a static string that has no interpolations in it, because the calling configuration already did all the work.

I suspect what you have here is a configuration that was written for a long-obsolete version of Terraform (v0.11 or earlier) where there wasn’t yet any for expressions in the language, and so this is effectively a long-winded alternative to a for expression, rather than really a template.

The good news is that this should be much more straightforward when using modern Terraform language features.

First let’s build the set of VPC CIDR blocks:

locals {
  all_vpc_cidr_blocks = toset(concat(
    data.terraform_remote_state.other_vpcs[*].outputs.vpc_cidr_block,
    [data.terraform_remote_state.mgmt_vpc.outputs.vpc_cidr_block],
  ))
}

This defines local.all_vpc_cidr_blocks to be a set of all of the CIDR block strings from both of the remote state results.

The other “template” in your example seems to be converting those CIDR blocks into netmask notation. It’s currently producing a single string for each input that has the base address, then a space, and then the netmask. In modern Terraform I would suggest making this use an object type instead, so you don’t need to do string manipulation to access the two parts separately:

locals {
  all_vpc_netmasks = toset([
    for cidr in local.all_vpc_cidr_blocks : {
      base    = cidrhost(cidr, 0)
      netmask = cidrnetmask(cidr)
    }
  ])
}

This defines local.all_vpc_netmasks as a set of objects where each has a base attribute and a netmask attribute, both of which are strings.

It would also be possible to adapt the above to sail generate just a single string with the two values separated by a space, if you find that more convenient, but an alternative that works with the set of objects as I wrote it above would be to stringify them as part of building the CLI argument they will eventually be used in:

formatlist(
  "--vpn-route \"%s %s\" "
  local.all_vpc_netmasks[*].base,
  local.all_vpc_netmasks[*].netmask,
)

…which therefore leaves the data in the more convenient set of objects form in case that’s useful in other parts of the configuration, while still generating the string representation that this command seems to expect.